path: root/app/app.lisp

;;;; app.lisp -- definition of CLI options and entry point.

;; Copyright (C) 2022  Colin Okay

;; This program is free software: you can redistribute it and/or modify
;; it under the terms of the GNU Affero General Public License as
;; published by the Free Software Foundation, either version 3 of the
;; License, or (at your option) any later version.

;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU Affero General Public License for more details.

;; You should have received a copy of the GNU Affero General Public License
;; along with this program.  If not, see <http://www.gnu.org/licenses/>.


(in-package :oneliners.cli.app)

;;; VERSION
(defparameter +ol-version+ "0.7.0")

;;; HELP TEXTS
(defparameter +oneliners-variables-help-text+
"
Oneliners may contain variables.  There are positional variables and
named variables.

POSITIONAL VARIABLES appear in the oneliner as a # followed by a
number, which must 1 or greater.  For example:

    echo Hello #1, Happy #2

The #1 and #2 are a positional variables. You might call the above
like

   ol run 8 Doofus Tuesday

Assuming that the above oneliner has ID 8, then \"Hello Doofus,
 Happy Tuesday\" would print to the console.

NAMED VARIABLES are similar. They appear in the oneliner as # followed
by a letter in the Roman alphabet, followed by any sequence of Roman
letters, numbers, or the symbol _.  For example:

   echo Hello #name you get a #thing

The #name and #thing are named variables. You might call the above like so:

  ol run 3 name=Goober thing='sock in the nose'

Which should print \"Hello Goober you get a sock in the nose\".

Finally, you can MIX POSITIONAL AND NAMED VARIABLES so long as, when
you run the oneliner, all positional variables appear first.
")

(defparameter +configure-your-edtior+
  "Adding explainations for oneliners, either with --add or --edit,
will use a default system editor. If you do not like the default
editor you may configure it by the exporting the EDITOR environment
variable to whatever you prefer.

E.g. in your .bashrc you might put 

export EDITOR=/usr/bin/zile 

")


;;; CLON SYNOPSIS DEFINITION 

(defsynopsis (:postfix "COMMAND [ARGS...]")
  (group (:header "SEARCHING FOR ONELINERS" :hidden t)
         (text :contents "Usage: ol [OPTIONS] search [TERMS...]")
         (text :contents " ")
         (text :contents "Search for oneliners that have been tagged with all of TERMS.")
         (text :contents "E.g. `ol search grep awk`")
         (text :contents " ")
         (text :contents "Options:")
         (lispobj :long-name "limit"
                  :argument-type :optional
                  :argument-name "NUMBER"
                  :default-value 10
                  :description "The maximum number of results to return."
                  :typespec 'integer)
         (flag :long-name "all-flagged"
               :description "Request that only flagged oneliners are returned. Without any TERMS, simply returns all flagged oneliners.")
         (flag :long-name "not-flagged"
               :description "Request that no flagged oneliners are returned with the search results. Does nothing without TERMS.")
         (flag :long-name "newest"
               :description "Return newest oneliners that match. Without any TERMS, simply returns the newest oneliners."))
  (group (:header "RUNNING ONELINERS" :hidden t)
         (text :contents "Usage: ol [OPTIONS] run <IDENTIFIER> [ARGS...]")
         (text :contents " ")
         (text :contents "Run the oneliner identified by IDENTIFIER, if it exists, with any required ARGS.")
         (text :contents "IDENTIFIER should either be the name or the unique numeric ID of a oneliner.")
         (text :contents "E.g. `ol run demo foo bar` # run \"demo\" with args \"foo\" and \"bar\"")
         (text :contents " ")
         (text :contents "Options:")
         (lispobj :long-name "timeout"
                  :argument-type :optional
                  :argument-name "SECONDS"
                  :default-value 1
                  :typespec 'integer 
                  :description "How many seconds to wait for standard output before giving up.")
         (flag :long-name "draft"
               :description "Indicates that you wish to run a draft of a oneliner identified by IDENTIFIER."))
  (group (:header "CLIPPING ONELINERS" :hidden t)
         (text :contents "Usage: ol clip <IDENTIFIER> [ARGS...]")
         (text :contents " ")
         (text :contents "Instead of running a oneliner, copy it to your system's clipboard")
         (text :contents "ol clip demo-1 foo extra=bar"))
  (group (:header "SHOWING INFORMATION ABOUT ONELINERS" :hidden t)
         (text :contents "Usage: ol show <IDENTIFIER>")
         (text :contents " ")
         (text :contents "Print information about a oneliner to the screen."))
  (group (:header "NEW ONELINERS" :hidden t)
         (text :contents "Usage: ol new")
         (text :contents " ")
         (text :contents "Interactively create a new oneliner and upload it to the server."))
  (group (:header "EDITING ONELINERS" :hidden t)
         (text :contents "Usage: ol edit <IDENTIFIER>")
         (text :contents " ")
         (text :contents "Interactively alter a oneliner and uplaod it to the server."))
  (group (:header "PUBLISHING ONELINERS" :hidden t)
         (text :contents "Usage: ol publish <DRAFT>")
         (text :contents " ")
         (text :contents "Submits a draft oneliner to the wiki server, and, when successful, deletes the draft."))
  (group (:header "FLAGGING AND UNFLAGGING ONELINERS" :hidden t)
         (text :contents "Usage: ol <flag | unflag> <IDENTIFIER>")
         (text :contents " ")
         (text :contents
               "Flag or unflag a oneliner. A flagged oneliner is marked as potentially hazardous and will prompt users before exectuion.")
         (text :contents
               "Flagged oneliners may also be specifically factor into search using the --all-flagged or --not-flagged search options."))
  (group (:header "LOCKING AND UNLOCKING ONELINERS" :hidden t)
         (text :contents "Usage: ol <lock | unlock> <IDENTIFIER>")
         (text :contents " ")
         (text :contents "(ADMINS ONLY) Lock or unlock a oneliner. A locked oneliner may not be altered or edited."))
  (group  (:header "REDEEMING INVITE TOKENS" :hidden t)
          (text :contents "Usage: ol redeem <INVITE> <HANDLE> <PASSWORD>")
          (text :contents " ")
          (text :contents "Redeem an invite token, INVITE, and reate a new contributor account on the wiki server with user handle and password."))
  (group (:header "INVITE TOKENS" :hidden t)
         (text :contents "Usage: ol invite")
         (text :contents " ")
         (text :contents "Generate a new invite token if you are allowed to do so."))
  (group (:header "LOGIN AND LOGOUT" :hidden t)
         (text :contents "Usage: ol <login | logout> [HANDLE PASWORD]")
         (text :contents " ")
         (text :contents "Login or logout. If logging in, provide a handle and password.")
         (text :contents "Once logged in to your configured server, an API access token will be written to your config file, allowing you to make contributions to the wiki."))
  (group (:header "PASSWORD CHANGES" :hidden t)
         (text :contents "Usage: ol password <OLD> <NEW> <REPEATED>")
         (text :contents " ")
         (text :contents "Change your password on the configured server."))
  (group (:header "SIGNATURE CHANGES" :hidden t)
         (text :contents "Usage: ol signature")
         (text :contents " ")
         (text :contents "Interactively update your contributor signature."))
  (group (:header "WHOIS CONTRIBUTOR" :hidden t)
         (text :contents "Usage: ol whois <HANDLE>")
         (text :contents " ")
         (text :contents "Print information about a contributor."))
  (group (:header "HELP MENU")
         (text :contents "Usage: ol help [COMMAND_SECTION]")
         (text :contents " ")
         (text :contents "Print a help menu. With no arguments, prints this help.")
         (text :contents  "Command sections include:")
         (text :contents  "search")
         (text :contents  "run")
         (text :contents  "clip")
         (text :contents  "show")
         (text :contents  "new")
         (text :contents  "edit")
         (text :contents "publish")
         (text :contents  "flag")
         (text :contents  "lock")
         (text :contents  "redeem")
         (text :contents  "invite")
         (text :contents  "login")
         (text :contents  "password")
         (text :contents  "signature")))

;;; HELPERS

(defun find-group-with-header (header)
  "This function should be built in. Is it? How to know? The
documentation is both extensive and trash.  Any manual that expects
you to go to sleep with it at night is written for the author more
than the users."
  (loop for item in (net.didierverna.clon::items *synopsis*)
        when (and (typep item 'net.didierverna.clon::group)
                  (string-equal header (net.didierverna.clon::header item)
                                :end2 (length header)))
          return item))

;;; MAIN ENTRY POINT

(defun main ()
  (make-context)
  (a:if-let (arguments (remainder))
    (destructuring-bind (command . args) arguments
      (let ((id-or-name
              (when  args
                (or (parse-integer (first args) :junk-allowed t)
                    (first args))))) 
        (cli:with-local-state 
          (ecase (a:make-keyword (string-upcase command))
            (:help
             (princ #\newline)
             (help-topic (first args)))
            (:search
             (cli:search-for-oneliners
              args
              (getopt :long-name "limit")
              (getopt :long-name "not-flagged")
              (getopt :long-name "all-flagged")
              (getopt :long-name "newest")))
            (:run
             (cli:run-item id-or-name (rest args)
                           :timeout (getopt :long-name "timeout")
                           :draftp (getopt :long-name "draft")))
            (:clip
             (cli:run-item id-or-name (rest args)
                           :force-clip t
                           :draftp (getopt :long-name "draft")))
            (:show
             (cli:print-item-explanation id-or-name))
            (:new
             (cli:add-new-oneliner))
            (:edit
             (cli:edit-item id-or-name (getopt :long-name "draft")))
            (:publish
             (cli::publish-draft id-or-name))
            (:flag
             (cli:flag-item id-or-name))
            (:unflag
             (cli:unflag-item id-or-name))
            (:lock
             (cli:lock-item id-or-name))
            (:unlock
             (cli:unlock-item id-or-name))
            (:redeem
             (unless (= 3 (length args))
               (help-topic "redeem")
               (uiop:quit))
             (apply 'cli:redeem-invite args))
            (:invite
             (cli:request-invite-code))
            (:login
             (unless (= 3 (length args))
               (help-topic "login")
               (uiop:quit))
             (apply 'cli:login args))
            (:logout
             (cli:revoke-access))
            (:password
             (unless (= 3 (length args))
               (help-topic "password")
               (uiop:quit))
             (apply 'cli:change-pw args))
            (:signature
             (cli:change-signature))
            (:whois
             (unless args
               (help-topic "whois")
               (uiop:quit))
             (cli:show-contributor (first args)))))))
    (help))
  (uiop:quit))

(defun help-topic (topic)
  (a:if-let (group (find-group-with-header topic))
    (help :item group)
    (help)))