;;;; pages.lisp -- html generation functions for dnd

(in-package :dnd)

(defmacro with-page ((&key title) &body body)
  `(with-html-string
     (:doctype)
     (:html
      (:head
       (:title ,title))
      (:body ,@body))))

(defun godess-shrine ()
  (with-page (:title "A Sacred Shrine")
    (:header
     (:h1 "Pray and become a hero..."))
    (:form :method "POST" :action "/godess-shrine"
	   (:label :for "NAME" "Enter the epithet by which the ages shall know thy hero:")
	   (:input :name "NAME")
	   (:button :type "submit" "Pray To The Goddess"))))

(defun doorkeeper (&key (message "Come ye player, Wot's yer name?"))
  (with-page (:title "Tavern Door")
    (:h1 message)
    (:form :method "POST" :action "/tavern-door"
	   (:label :for "NICK" "Wut's yer handle?:")
	   (:input :name "NICK")
	   (:button :type "submit" "Announce Thyself"))
    (:h2 "Eh? Ye need to announce thyeself?")
    (:a :href "/register" "Follow me...")))

(defun register ()
  (with-page (:title "Register Player")
    (:header
     (:h1 "Choose a Nickname Player"))
    (:form :method "POST" :action "/register"
           (:label  :for "NICK" "Choose a nickname. No spaces. Letters, Numbers, and -._")
           (:input :name "NICK" :placeholder "superbob")
           (:button :type "submit" "Register"))))

(defun tavern (player)
  (with-page (:title "A Bustling Tavern")
    (navbar)
    (:div
     :class "heroes-container"
     (:h2 "Heroes of rampant renown:")
     (hall-of-heroes))))

(defun navbar ()
  (with-html
      (:nav :class "navbar" :aria-label "Navigation"
	    (:div :class "logo" :aria-label "DND logo" "DND")
	    (:ul :class "nav-links" :aria-label "Nav links"
	         (:li (:a :href "/hero" :aria-label "Hero profile" "🧝"))
	         (:li (:a :href "/inventory" :aria-label "Inventory" "🎒"))
	         (:li (:a :href "/quests" :aria-label "Quests" "📜"))
	         (:li (:a :href "/tavern" :aria-label "Tavern" "🍺"))))))

(defun hall-of-heroes ()
  (with-html
      (:ul :class "hall-of-heroes"
           (dolist (hero (all-heroes))
	     (:li (hero-name hero)
                  "the"
                  (hero-class hero)
                  (hero-title hero))))))

(defgeneric render (element)
  (:documentation "Render an element as HTML"))

(defclass page ()
  ((title
    :reader title
    :initarg :title
    :documentation "Page title ")
   (main
    :reader main
    :initarg :main
    :initform ""
    :documentation "Main content for a page.")))

(defmethod render ((doc page))
  (with-html
    (:doctype)
    (:html
     (:head (:title (title doc)))
     (:body
      (main doc)))))

(defclass navable ()
  ((nav-links
    :reader nav-links
    :initarg :nav-links
    :type list))
  (:documentation "Mixin for a PAGE class with navigation."))

(defclass nav-link ()
  ((target :initarg :target)
   (text :initarg :text)
   (icon :initarg :icon :initform nil)
   (label :initarg :label :initform nil)))

(defmethod render ((element nav-link))
  (with-slots (target icon label text) element
    (with-html
      (:li (:a :href target :aria-label label icon text)))))

(defclass page-with-nav (page navable)
  ())

(defmethod render ((doc page-with-nav))
  (with-html
    (:doctype)
    (:html
     (:head (:title (title doc)))
     (:body
      (:nav (:ul (mapc #'render (nav-links doc))))
      (:main (main doc))))))

;; (let* ((link (make-instance
;; 	     'nav-link :target "/moo" :label "goo" :icon "🍺" :text "Tavern"))
;;        (foo (make-instance
;; 	     'page-with-nav :title "goober" :main "Content" :nav-links (list link link))))
;;   (render foo))