;;;; examples/11-canvas-geometry.lisp

(defpackage #:ww.examples/11
  (:use #:cl)
  (:export #:start))

(in-package :ww.examples/11)

(defclass geo-demo (ww:application) ())

(ww:defhandler quit
    (ww::on-keydown (app scancode)
      (when (eql :scancode-q scancode)
        (ww::stop))))

(defmethod ww:boot ((app geo-demo))
  (let ((canvas
          (make-instance 'ww:canvas
                         :pixel-width 200
                         :pixel-height 200)))
    ;; stretch canvas over the whole app
    (setf (ww:width canvas) (ww::application-width app)
          (ww:height canvas) (ww::application-height app))

    ;; add it to the display tree
    (ww:add-unit app canvas)

    ;; draw a circle
    (ww::with-grid-circle (x y) (150 50 30 :interiorp t)
      (ww::with-pixel (r g b a) (ww::pixel canvas x y)
        (setf r (mod (* 3 x y) 256)
              g (mod (+ x x) 256)
              b (mod (* y y) 256))))

    ;; draw a bunch of circles
    (loop
      for cx from 0 to 50 by 5 
      for cy from 0 to 50 by 5 do
        (ww::with-grid-circle (x y) ((+ 100 cx) (+ 100 cy) 10)
          (ww::with-pixel (r g b a) (ww::pixel canvas x y)
            (setf r (mod (* x y) 256)
                  g (mod (* x x) 256)
                  b (mod (* y x) 256)))))

    ;; draw a random pentagonal thing
    (let ((path
            (loop repeat 7
                  collect (list (+ 10 (random 80))
                                (+ 10 (random 80))))))
      (ww::with-grid-path (x y) (path :autoclosep t :interiorp t)
        (ww::with-pixel (r g b a) (ww::pixel canvas x y)
          (setf r (mod (* 2 y) 256)
                g (mod (* 3 x) 256)
                b (mod (* x y) 256)))))

        (let ((path
            (loop repeat 20
                  collect (list (+ 10 (random 80))
                                (+ 110 (random 80))))))
      (ww::with-grid-path (x y) (path :autoclosep t)
        (ww::with-pixel (r g b a) (ww::pixel canvas x y)
          (setf r (mod (* 2 y) 256)
                g (mod (* 3 x) 256)
                b (mod (* x y) 256)))))
    
    ;; blit the canvas
    (ww::blit canvas)

    ;; quit handler
    (ww:add-handler app #'quit)
    (ww:add-handler canvas #'quit)))

(defun start (&optional (side 500))
  (ww::start
   (make-instance
    'geo-demo
    :fps 10
    :width side
    :height side
    :title "Pixels Geometry")))