;;;; zipper.lisp

(in-package :vampire)

(defun zip-playlist (playlist)
  "Compresses playlist tracks into a zip archive."
  (with-temp-dir (tmpdir)
    (let ((zip-dir (zipped-playlist-path)))
      (ensure-directories-exist zip-dir)
      (org.shirakumo.zippy:compress-zip
       (copy-audio-files-for-download playlist tmpdir) zip-dir :if-exists :overwrite))))

(defun zip-track-filename (track pos)
  "Return a filename for a track. `NN-ARTIST-ALBUM-TITLE.CODEC'"
  (with-slots (artist album title codec) track
    (format nil "~2,'0d-~a-~a-~a.~a" pos
	    (clean-slashes artist) (clean-slashes album) (clean-slashes title) codec)))

(defun zipped-playlist-filename (playlist)
  "Return a url-safe zip filename for a playlist."
  (concatenate 'string (clean-slashes (playlist-title playlist)) ".zip"))

(defun zipped-playlist-path (playlist)
  "Returns the zipped playlist path relative to the configured static directory."
  (merge-pathnames (pathname-utils:to-relative (zipped-playlist-url playlist))
                   (static-directory *config*)))

(defun zipped-playlist-url (playlist)
  "Returns the url where the playlist's zip file is expected to exist."
  (merge-pathnames (zipped-playlist-filename playlist) "/media/bundled-playlists/"))

(defun copy-audio-files-for-download (playlist dir)
  "Copies all playlist tracks into a temporary directory and returns a list of the pathnames."
  (loop for track in (playlist-tracks playlist)
        for pos from 1
        for file = (track-file track)
        for dest = (merge-pathnames (zip-track-filename track pos) dir)
        do (uiop:copy-file file dest)
        collect dest))